Как можно экспортировать базу MySQL размеров 3гб?

[strelkovandrey]

Добрый день.
Имеется база данных размеров в 3гб. Необходимо её экспортировать для последующего импорта в другом месте. PHPMyAdmin зависнет наверняка.
Как можно через консоль экспортнуть?

[Ink0gnit0]

Создайте cmd-файл со следующим содержимым:

@echo off
setlocal
set usr=root
set pwd=
set db_name=mydb
set backups_path=d:\backups\
set PATH=%PATH%;C:\openserver\modules\database\Mysql-X.X\bin;

mkdir %backups_path% >nul 2>nul

for /f "tokens=1-3 delims=/. " %%a in ('date /t') do (set backup_date=%%c%%b%%a)
for /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set backup_time=%%a%%b)

mysqldump --user=%usr% --password=%pwd% --databases %db_name% > %backups_path%%db_name%_%backup_date%_%backup_time%.sql

pause

Задайте параметры доступа к БД и укажите нужные пути.

[strelkovandrey]

Большое спасибо!

[vlad_luxor]

А как сделать импорт подобным образом?

[Ink0gnit0]

vlad_luxor,

@echo off
setlocal
set usr=root
set pwd=
set db_name=mydb
set PATH=%PATH%;C:\openserver\modules\database\Mysql-X.X\bin;
set backup_file=d:\backups\backup_file.sql

if exist %backup_file% (goto :DO_RESTORE) else (goto :FILE_NOT_FOUND)

:DO_RESTORE
echo Восстановление БД '%db_name%' из файла '%backup_file%'
mysql --user=%usr% --password=%pwd% %db_name% < %backup_file%
echo Восстановление выполнено!
goto :END

:FILE_NOT_FOUND
echo Файл '%backup_file%' не найден

:END
pause

[vlad_luxor]

Ink0gnit0, благодарочка!

[Tandaran]

Создайте cmd-файл со следующим содержимым:

@echo off
setlocal
set usr=root
set pwd=
set db_name=mydb
set backups_path=d:\backups\
set PATH=%PATH%;C:\openserver\modules\database\Mysql-X.X\bin;

mkdir %backups_path% >nul 2>nul

for /f "tokens=1-3 delims=/. " %%a in ('date /t') do (set backup_date=%%c%%b%%a)
for /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set backup_time=%%a%%b)

mysqldump --user=%usr% --password=%pwd% --databases %db_name% > %backups_path%%db_name%_%backup_date%_%backup_time%.sql

pause

Задайте параметры доступа к БД и укажите нужные пути.

Добрый день! У меня также файл базы данный большой, 143 МБ, а в пхп админе более 100 выгрузить нельзя, этот способ также подойдет чтобы сделать бэкап базы данных?